^Syntax
InlineAttribute →
      inline ( always )
    | inline ( never )
    | inline

CollapseDebuginfoAttribute → collapse_debuginfo ( CollapseDebuginfoOption )

CollapseDebuginfoOption →
      yes
    | no
    | external

InnerAttribute → # ! [ Attr ]

OuterAttribute → # [ Attr ]

Attr →
      SimplePath AttrInput^?
    | unsafe ( SimplePath AttrInput^? )

AttrInput →
      DelimTokenTree
    | = Expression

MetaItem →
      SimplePath
    | SimplePath = Expression
    | SimplePath ( MetaSeq^? )

MetaSeq →
    MetaItemInner ( , MetaItemInner )^* ,^?

MetaItemInner →
      MetaItem
    | Expression

MetaWord →
    IDENTIFIER

MetaNameValueStr →
    IDENTIFIER = ( STRING_LITERAL | RAW_STRING_LITERAL )

MetaListPaths →
    IDENTIFIER ( ( SimplePath ( , SimplePath )^* ,^? )^? )

MetaListIdents →
    IDENTIFIER ( ( IDENTIFIER ( , IDENTIFIER )^* ,^? )^? )

MetaListNameValueStr →
    IDENTIFIER ( ( MetaNameValueStr ( , MetaNameValueStr )^* ,^? )^? )

ProcMacroDeriveAttribute →
    proc_macro_derive ( DeriveMacroName ( , DeriveMacroAttributes )^? ,^? )

DeriveMacroName → IDENTIFIER

DeriveMacroAttributes →
    attributes ( ( IDENTIFIER ( , IDENTIFIER )^* ,^? )^? )

Show Railroad

^Lexer
COMMENT →
      LINE_COMMENT
    | INNER_LINE_DOC
    | OUTER_LINE_DOC
    | INNER_BLOCK_DOC
    | OUTER_BLOCK_DOC
    | BLOCK_COMMENT

LINE_COMMENT →
      // ( ~[/ ! LF] | // ) ~LF^*
    | // EOF
    | //_{immediately followed by LF}

BLOCK_COMMENT →
    /* ^
      ( BLOCK_COMMENT | BLOCK_CHAR )^*
    */

INNER_LINE_DOC →
    //! ^ LINE_DOC_COMMENT_CONTENT ( LF | EOF )

LINE_DOC_COMMENT_CONTENT → ( !CR ~LF )^*

INNER_BLOCK_DOC →
    /*! ^ ( NESTED_BLOCK_DOC_COMMENT | DOC_BLOCK_CHAR )^* */

OUTER_LINE_DOC →
    /// ^ LINE_DOC_COMMENT_CONTENT ( LF | EOF )

OUTER_BLOCK_DOC →
    /** ![* /]
      ^
      ~[* CR]
      ( NESTED_BLOCK_DOC_COMMENT | DOC_BLOCK_CHAR )^*
    */

BLOCK_CHAR → !*/ CHAR

DOC_BLOCK_CHAR → ( !( */ | CR ) CHAR )

NESTED_BLOCK_DOC_COMMENT →
    /* ( NESTED_BLOCK_DOC_COMMENT | DOC_BLOCK_CHAR )^* */

IDENTIFIER_OR_KEYWORD → ( XID_Start | _ ) XID_Continue^*

XID_Start → <XID_Start defined by Unicode>

XID_Continue → <XID_Continue defined by Unicode>

RAW_IDENTIFIER → r# IDENTIFIER_OR_KEYWORD

NON_KEYWORD_IDENTIFIER → IDENTIFIER_OR_KEYWORD_{except a strict or reserved keyword}

IDENTIFIER → NON_KEYWORD_IDENTIFIER | RAW_IDENTIFIER

RESERVED_RAW_IDENTIFIER →
    r# ( _ | crate | self | Self | super ) !XID_Continue

CHAR → [U+0000-U+D7FF U+E000-U+10FFFF] // a Unicode scalar value

ASCII → [U+0000-U+007F]

NUL → U+0000

EOF → !CHAR // End of file or input

STRICT_KEYWORDS →
      _
    | as
    | async
    | await
    | break
    | const
    | continue
    | crate
    | dyn
    | else
    | enum
    | extern
    | false
    | fn
    | for
    | if
    | impl
    | in
    | let
    | loop
    | match
    | mod
    | move
    | mut
    | pub
    | ref
    | return
    | self
    | Self
    | static
    | struct
    | super
    | trait
    | true
    | type
    | unsafe
    | use
    | where
    | while

RESERVED_KEYWORDS →
      abstract
    | become
    | box
    | do
    | final
    | gen
    | macro
    | override
    | priv
    | try
    | typeof
    | unsized
    | virtual
    | yield

WEAK_KEYWORDS →
      'static
    | macro_rules
    | raw
    | safe
    | union

SHEBANG →
    #! !( ( WHITESPACE | LINE_COMMENT | SHEBANG_BLOCK_COMMENT )^* [ )
    ~LF^* ( LF | EOF )

SHEBANG_BLOCK_COMMENT →
    /* !( ! | * ![* /] )
      ( SHEBANG_NESTED_BLOCK_COMMENT | ( !( */ | /* ) CHAR ) )^*
    */

SHEBANG_NESTED_BLOCK_COMMENT →
    /*
      ( SHEBANG_NESTED_BLOCK_COMMENT | ( !( */ | /* ) CHAR ) )^*
    */

Token →
      RESERVED_TOKEN
    | RAW_IDENTIFIER
    | CHAR_LITERAL
    | STRING_LITERAL
    | RAW_STRING_LITERAL
    | BYTE_LITERAL
    | BYTE_STRING_LITERAL
    | RAW_BYTE_STRING_LITERAL
    | C_STRING_LITERAL
    | RAW_C_STRING_LITERAL
    | FLOAT_LITERAL
    | INTEGER_LITERAL
    | LIFETIME_TOKEN
    | PUNCTUATION
    | IDENTIFIER_OR_KEYWORD

SUFFIX →
      _ ^ XID_Continue⁺
    | XID_Start XID_Continue^*

CHAR_LITERAL →
    '
        ( ~[' \ LF CR TAB] | QUOTE_ESCAPE | ASCII_ESCAPE | UNICODE_ESCAPE )
    ' SUFFIX^?

QUOTE_ESCAPE → \' | \"

ASCII_ESCAPE →
      \x OCT_DIGIT HEX_DIGIT
    | \n | \r | \t | \\ | \0

UNICODE_ESCAPE →
    \u{ ( HEX_DIGIT _^* )^1..=6_{valid hex char value} }

STRING_LITERAL →
    " (
        ~[" \ CR]
      | QUOTE_ESCAPE
      | ASCII_ESCAPE
      | UNICODE_ESCAPE
      | STRING_CONTINUE
    )^* " SUFFIX^?

STRING_CONTINUE → \ LF [TAB LF CR SP]^*

RAW_STRING_LITERAL →
      r " ^ RAW_STRING_CONTENT " SUFFIX^?
    | r #^n:1..=255 ^ " RAW_STRING_CONTENT_HASHED " #ⁿ SUFFIX^?

RAW_STRING_CONTENT → ( !" ~CR )^*

RAW_STRING_CONTENT_HASHED → ( !( " #ⁿ ) ~CR )^*

BYTE_LITERAL →
    b' ^ ( ASCII_FOR_CHAR | BYTE_ESCAPE ) ' SUFFIX^?

ASCII_FOR_CHAR → ![' \ LF CR TAB] ASCII

BYTE_ESCAPE →
      \x HEX_DIGIT HEX_DIGIT
    | \n | \r | \t | \\ | \0 | \' | \"

BYTE_STRING_LITERAL →
    b" ^ ( ASCII_FOR_STRING | BYTE_ESCAPE | STRING_CONTINUE )^* " SUFFIX^?

ASCII_FOR_STRING → ![" \ CR] ASCII

RAW_BYTE_STRING_LITERAL →
      br " ^ RAW_BYTE_STRING_CONTENT " SUFFIX^?
    | br #^n:1..=255 ^ " RAW_BYTE_STRING_CONTENT_HASHED " #ⁿ SUFFIX^?

RAW_BYTE_STRING_CONTENT → ( !" ASCII_FOR_RAW )^*

RAW_BYTE_STRING_CONTENT_HASHED → ( !( " #ⁿ ) ASCII_FOR_RAW )^*

ASCII_FOR_RAW → !CR ASCII

C_STRING_LITERAL →
    c" ^ (
        ~[" \ CR NUL]
      | !( \0 | \x00 ) BYTE_ESCAPE
      | !( \u{ ( 0 _^* )^1..=6 } ) UNICODE_ESCAPE
      | STRING_CONTINUE
    )^* " SUFFIX^?

RAW_C_STRING_LITERAL →
      cr " ^ RAW_C_STRING_CONTENT " SUFFIX^?
    | cr #^n:1..=255 ^ " RAW_C_STRING_CONTENT_HASHED " #ⁿ SUFFIX^?

RAW_C_STRING_CONTENT → ( !" ~[CR NUL] )^*

RAW_C_STRING_CONTENT_HASHED → ( !( " #ⁿ ) ~[CR NUL] )^*

INTEGER_LITERAL →
    ( BIN_LITERAL | OCT_LITERAL | HEX_LITERAL | DEC_LITERAL )
    ^ !RESERVED_FLOAT SUFFIX^?

DEC_LITERAL → DEC_DIGIT ( DEC_DIGIT | _ )^*

BIN_LITERAL → 0b ^ _^* BIN_DIGIT ( BIN_DIGIT | _ )^* ![e E 2-9]

OCT_LITERAL → 0o ^ _^* OCT_DIGIT ( OCT_DIGIT | _ )^* ![e E 8-9]

HEX_LITERAL → 0x ^ _^* HEX_DIGIT ( HEX_DIGIT | _ )^*

BIN_DIGIT → [0-1]

OCT_DIGIT → [0-7]

DEC_DIGIT → [0-9]

HEX_DIGIT → [0-9 a-f A-F]

RESERVED_FLOAT → . !( . | _ | XID_Start )

TUPLE_INDEX → DEC_LITERAL | BIN_LITERAL | OCT_LITERAL | HEX_LITERAL

FLOAT_LITERAL →
      DEC_LITERAL ( . DEC_LITERAL )^? FLOAT_EXPONENT SUFFIX^?
    | DEC_LITERAL . DEC_LITERAL SUFFIX^?
    | DEC_LITERAL . !( . | _ | XID_Start )

FLOAT_EXPONENT →
    ( e | E ) ^ ( + | - )^? _^* DEC_DIGIT ( DEC_DIGIT | _ )^*

LIFETIME_TOKEN →
      RAW_LIFETIME
    | ' IDENTIFIER_OR_KEYWORD !'

LIFETIME_OR_LABEL →
      RAW_LIFETIME
    | ' NON_KEYWORD_IDENTIFIER !'

RAW_LIFETIME →
    'r# ^ IDENTIFIER_OR_KEYWORD !'

RESERVED_RAW_LIFETIME → 'r# ( _ | crate | self | Self | super ) !( ' | XID_Continue )

PUNCTUATION →
      ...
    | ..=
    | <<=
    | >>=
    | !=
    | %=
    | &&
    | &=
    | *=
    | +=
    | -=
    | ->
    | ..
    | /=
    | ::
    | <-
    | <<
    | <=
    | ==
    | =>
    | >=
    | >>
    | ^=
    | |=
    | ||
    | !
    | #
    | $
    | %
    | &
    | (
    | )
    | *
    | +
    | ,
    | -
    | .
    | /
    | :
    | ;
    | <
    | =
    | >
    | ?
    | @
    | [
    | ]
    | ^
    | {
    | |
    | }
    | ~

RESERVED_TOKEN →
      RESERVED_GUARDED_STRING_LITERAL
    | RESERVED_POUNDS
    | RESERVED_RAW_IDENTIFIER
    | RESERVED_RAW_LIFETIME
    | RESERVED_TOKEN_DOUBLE_QUOTE
    | RESERVED_TOKEN_LIFETIME
    | RESERVED_TOKEN_POUND
    | RESERVED_TOKEN_SINGLE_QUOTE

RESERVED_TOKEN_DOUBLE_QUOTE →
    IDENTIFIER_OR_KEYWORD_{except b or c or r or br or cr} "

RESERVED_TOKEN_SINGLE_QUOTE →
    IDENTIFIER_OR_KEYWORD_{except b} '

RESERVED_TOKEN_POUND →
    IDENTIFIER_OR_KEYWORD_{except r or br or cr} #

RESERVED_TOKEN_LIFETIME →
    ' IDENTIFIER_OR_KEYWORD_{except r} #

RESERVED_GUARDED_STRING_LITERAL → #⁺ STRING_LITERAL

RESERVED_POUNDS → #^2..

WHITESPACE →
      U+0009 // Horizontal tab, '\t'
    | U+000A // Line feed, '\n'
    | U+000B // Vertical tab
    | U+000C // Form feed
    | U+000D // Carriage return, '\r'
    | U+0020 // Space, ' '
    | U+0085 // Next line
    | U+200E // Left-to-right mark
    | U+200F // Right-to-left mark
    | U+2028 // Line separator
    | U+2029 // Paragraph separator

TAB → U+0009 // Horizontal tab, '\t'

LF → U+000A // Line feed, '\n'

CR → U+000D // Carriage return, '\r'

SP → U+0020 // Space, ' '

Show Railroad

^Syntax
ConfigurationPredicate →
      ConfigurationOption
    | ConfigurationAll
    | ConfigurationAny
    | ConfigurationNot
    | true
    | false

ConfigurationOption →
    IDENTIFIER ( = ( STRING_LITERAL | RAW_STRING_LITERAL ) )^?

ConfigurationAll →
    all ( ConfigurationPredicateList^? )

ConfigurationAny →
    any ( ConfigurationPredicateList^? )

ConfigurationNot →
    not ( ConfigurationPredicate )

ConfigurationPredicateList →
    ConfigurationPredicate ( , ConfigurationPredicate )^* ,^?

CfgAttribute → cfg ( ConfigurationPredicate )

CfgAttrAttribute → cfg_attr ( ConfigurationPredicate , CfgAttrs^? )

CfgAttrs → Attr ( , Attr )^* ,^?

CfgSelect → CfgSelectArms^?

CfgSelectArms →
    CfgSelectConfigurationPredicate =>
    (
        { ^ TokenTree } ,^? CfgSelectArms^?
      | ExpressionWithBlockNoAttrs ,^? CfgSelectArms^?
      | ExpressionWithoutBlockNoAttrs ( , CfgSelectArms^? )^?
    )

CfgSelectConfigurationPredicate →
    ConfigurationPredicate | _

Show Railroad

^Syntax
Crate →
    InnerAttribute^*
    Item^*

AssociatedItem →
    OuterAttribute^* (
        MacroInvocationSemi
      | ( Visibility^? ( TypeAlias | ConstantItem | Function ) )
    )

ConstantItem →
    const ( IDENTIFIER | _ ) : Type ( = Expression )^? ;

Enumeration →
    enum IDENTIFIER GenericParams^? WhereClause^? { EnumVariants^? }

EnumVariants → EnumVariant ( , EnumVariant )^* ,^?

EnumVariant →
    OuterAttribute^* Visibility^?
    IDENTIFIER ( EnumVariantTuple | EnumVariantStruct )^? EnumVariantDiscriminant^?

EnumVariantTuple → ( TupleFields^? )

EnumVariantStruct → { StructFields^? }

EnumVariantDiscriminant → = Expression

ExternCrate → extern crate CrateRef AsClause^? ;

CrateRef → IDENTIFIER | self

AsClause → as ( IDENTIFIER | _ )

ExternBlock →
    unsafe^? extern Abi^? {
        InnerAttribute^*
        ExternalItem^*
    }

ExternalItem →
    OuterAttribute^* (
        MacroInvocationSemi
      | Visibility^? StaticItem
      | Visibility^? Function
    )

Function →
    FunctionQualifiers fn IDENTIFIER GenericParams^?
        ( FunctionParameters^? )
        FunctionReturnType^? WhereClause^?
        ( BlockExpression | ; )

FunctionQualifiers → const^? async^? ItemSafety^? ( extern Abi^? )^?

ItemSafety → safe | unsafe

Abi → STRING_LITERAL | RAW_STRING_LITERAL

FunctionParameters →
      SelfParam ,^?
    | ( SelfParam , )^? FunctionParam ( , FunctionParam )^* ,^?